meson.build 9.23 KB
Newer Older
Marvin Scholz's avatar
Marvin Scholz committed
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26
# Copyright © 2018, VideoLAN and dav1d authors
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#
# 1. Redistributions of source code must retain the above copyright notice, this
#    list of conditions and the following disclaimer.
#
# 2. Redistributions in binary form must reproduce the above copyright notice,
#    this list of conditions and the following disclaimer in the documentation
#    and/or other materials provided with the distribution.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR
# ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

project('dav1d', ['c'],
    version: '0.0.1',
27
    default_options: ['c_std=c99'],
Marvin Scholz's avatar
Marvin Scholz committed
28 29 30 31
    meson_version: '>= 0.47.0')

dav1d_src_root = meson.current_source_dir()
cdata = configuration_data()
Marvin Scholz's avatar
Marvin Scholz committed
32
cdata_asm = configuration_data()
Marvin Scholz's avatar
Marvin Scholz committed
33 34
cc = meson.get_compiler('c')

35 36
# On windows, we use a compatibility layer to emulate pthread
if host_machine.system() != 'windows'
Marvin Scholz's avatar
Marvin Scholz committed
37 38
    thread_dependency = dependency('threads')
else
39
    thread_dependency = declare_dependency(sources: ['src/win32/thread.c'])
40
endif
Marvin Scholz's avatar
Marvin Scholz committed
41

42 43 44 45 46 47 48 49 50
dav1d_inc_dirs = include_directories(['include', 'include/dav1d'])

#
# Option handling
#
dav1d_bitdepths = get_option('bitdepths')
foreach bitdepth : dav1d_bitdepths
    cdata.set('CONFIG_@0@BPC'.format(bitdepth), 1)
endforeach
Marvin Scholz's avatar
Marvin Scholz committed
51 52 53 54 55 56

#
# OS/Compiler feature detection
#

feature_defines = [
57
    ['_POSIX_C_SOURCE',             '200112L'], # POSIX.1–2001 (IEEE Std 1003.1-2001)
Marvin Scholz's avatar
Marvin Scholz committed
58 59 60 61 62 63 64 65 66 67 68 69 70 71 72
]

if host_machine.system() == 'windows'
    feature_defines += [
            ['_WIN32_WINNT',                0x0601],
            ['UNICODE',                     1], # Define to 1 for Unicode (Wide Chars) APIs
            ['_UNICODE',                    1], # Define to 1 for Unicode (Wide Chars) APIs
            ['__USE_MINGW_ANSI_STDIO',      1], # Define to force use of MinGW printf
    ]
endif

if not cc.check_header('stdatomic.h')
    error('Atomics not supported')
endif

73 74 75
stackalign_flag = []
stackrealign_flag = []

76 77 78 79
if host_machine.cpu_family().startswith('x86')
    if cc.has_argument('-mpreferred-stack-boundary=5')
        stackalign_flag = ['-mpreferred-stack-boundary=5']
        stackrealign_flag = ['-mincoming-stack-boundary=4']
Marvin Scholz's avatar
Marvin Scholz committed
80 81 82
        cdata_asm.set('STACK_ALIGNMENT', 32)
        cdata.set('STACK_ALIGNMENT', 32)
    elif cc.has_argument('-mpreferred-stack-boundary=4')
83 84
        stackalign_flag = ['-mpreferred-stack-boundary=4']
        stackrealign_flag = ['-mincoming-stack-boundary=4']
Marvin Scholz's avatar
Marvin Scholz committed
85 86
        cdata_asm.set('STACK_ALIGNMENT', 16)
        cdata.set('STACK_ALIGNMENT', 16)
87 88 89
    elif cc.has_argument('-mstack-alignment=32')
        stackalign_flag = ['-mstack-alignment=32']
        stackrealign_flag = ['-mstackrealign']
Marvin Scholz's avatar
Marvin Scholz committed
90 91
        cdata_asm.set('STACK_ALIGNMENT', 32)
        cdata.set('STACK_ALIGNMENT', 32)
92
    else
Marvin Scholz's avatar
Marvin Scholz committed
93 94 95 96 97 98 99
        if host_machine.cpu_family() == 'x86_64'
            cdata_asm.set('STACK_ALIGNMENT', 16)
            cdata.set('STACK_ALIGNMENT', 16)
        else
            cdata_asm.set('STACK_ALIGNMENT', 4)
            cdata.set('STACK_ALIGNMENT', 4)
        endif
100
    endif
Marvin Scholz's avatar
Marvin Scholz committed
101 102
endif

Marvin Scholz's avatar
Marvin Scholz committed
103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127
if host_machine.cpu_family().startswith('x86')
    cdata.set10('ARCH_X86', true)
    if host_machine.cpu_family() == 'x86_64'
        cdata_asm.set10('ARCH_X86_64', true)
        cdata.set10('ARCH_X86_64', true)
        cdata_asm.set10('ARCH_X86_32', false)
        cdata.set10('ARCH_X86_32', false)

        cdata_asm.set10('PIC', true)
    else
        cdata_asm.set10('ARCH_X86_64', false)
        cdata.set10('ARCH_X86_64', false)
        cdata_asm.set10('ARCH_X86_32', true)
        cdata.set10('ARCH_X86_32', true)
    endif
else
    cdata.set10('ARCH_X86', false)
    cdata.set10('ARCH_X86_64', false)
    cdata.set10('ARCH_X86_32', false)
endif

if cc.symbols_have_underscore_prefix()
    cdata_asm.set10('PREFIX', true)
endif

Marvin Scholz's avatar
Marvin Scholz committed
128 129 130 131 132 133
if cc.has_argument('-fvisibility=hidden')
    add_project_arguments('-fvisibility=hidden', language: 'c')
else
    warning('Compiler does not support -fvisibility=hidden, all symbols will be public!')
endif

134
if cc.has_function('posix_memalign', prefix: '#include <stdlib.h>', args: ['-D_POSIX_C_SOURCE=200112L'])
Marvin Scholz's avatar
Marvin Scholz committed
135 136 137 138 139
    cdata.set('HAVE_POSIX_MEMALIGN', 1)
elif cc.has_function('_aligned_malloc', prefix: '#include <malloc.h>')
    cdata.set('HAVE_ALIGNED_MALLOC', 1)
endif

140 141 142 143
if cc.check_header('unistd.h')
    cdata.set('HAVE_UNISTD_H', 1)
endif

144 145
if (get_option('buildtype') != 'debug' and
    get_option('buildtype') != 'plain')
146 147 148
    add_project_arguments('-fomit-frame-pointer', '-ffast-math',
        language: 'c')
endif
Marvin Scholz's avatar
Marvin Scholz committed
149

150 151 152 153 154 155
warning_flags = [
  '-Wundef',
  '-Wvla', # should be '-Werror=vla
]

add_project_arguments(cc.get_supported_arguments(warning_flags), language: 'c')
Marvin Scholz's avatar
Marvin Scholz committed
156 157 158 159 160

foreach f : feature_defines
   cdata.set(f.get(0), f.get(1))
endforeach

Marvin Scholz's avatar
Marvin Scholz committed
161 162 163 164
is_asm_enabled = (get_option('build_asm') == true and
    host_machine.cpu_family().startswith('x86'))
cdata.set10('HAVE_ASM', is_asm_enabled)

Marvin Scholz's avatar
Marvin Scholz committed
165 166 167 168 169 170
#
# Generate config headers
#

config_h_target = configure_file(output: 'config.h', configuration: cdata)

Marvin Scholz's avatar
Marvin Scholz committed
171 172 173 174
if is_asm_enabled
    config_asm_target = configure_file(output: 'config.asm', output_format: 'nasm', configuration: cdata_asm)
endif

Marvin Scholz's avatar
Marvin Scholz committed
175 176
subdir('include')

177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199
#
# dav1d library
#
libdav1d_tmpl_sources = files(
    'src/ipred.c',
    'src/itx.c',
    'src/ipred_prepare.c',
    'src/lf_apply.c',
    'src/loopfilter.c',
    'src/mc.c',
    'src/cdef_apply.c',
    'src/cdef.c',
    'src/lr_apply.c',
    'src/looprestoration.c',
    'src/recon.c'
)

entrypoints_src = files(
    'src/lib.c',
    'src/thread_task.c'
)
entrypoints_lib = static_library(
    'libdav1dentrypoint',
200
    entrypoints_src, rev_target,
201
    include_directories: dav1d_inc_dirs,
202
    c_args: stackrealign_flag,
203
    install: false,
204
    build_by_default: false,
205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227
)
entrypoints_objs = entrypoints_lib.extract_all_objects()

libdav1d_sources = files(
    'src/picture.c',
    'src/data.c',
    'src/ref.c',
    'src/getbits.c',
    'src/obu.c',
    'src/decode.c',
    'src/cdf.c',
    'src/msac.c',
    'src/tables.c',
    'src/scan.c',
    'src/dequant_tables.c',
    'src/intra_edge.c',
    'src/lf_mask.c',
    'src/ref_mvs.c',
    'src/warpmv.c',
    'src/wedge.c',
    'src/qm.c',
)

Marvin Scholz's avatar
Marvin Scholz committed
228
if is_asm_enabled
Henrik Gramner's avatar
Henrik Gramner committed
229 230 231
    libdav1d_sources += files(
        'src/x86/cpu.c',
    )
Henrik Gramner's avatar
Henrik Gramner committed
232 233 234
    libdav1d_tmpl_sources += files(
        'src/x86/mc_init.c',
    )
Henrik Gramner's avatar
Henrik Gramner committed
235 236
    libdav1d_sources_asm = files(
        'src/x86/cpuid.asm',
Henrik Gramner's avatar
Henrik Gramner committed
237
        'src/x86/mc.asm',
Henrik Gramner's avatar
Henrik Gramner committed
238
    )
Marvin Scholz's avatar
Marvin Scholz committed
239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271

    nasm = find_program('nasm')

    if host_machine.system() == 'windows'
        nasm_format = 'win'
    elif host_machine.system() == 'darwin'
        nasm_format = 'macho'
    else
        nasm_format = 'elf'
    endif
    if host_machine.cpu_family() == 'x86_64'
        nasm_format += '64'
    else
        nasm_format += '32'
    endif

    nasm_gen = generator(nasm,
        output: '@BASENAME@.obj',
        depfile: '@BASENAME@.obj.ndep',
        arguments: [
            '-f', nasm_format,
            '-I', '@CURRENT_SOURCE_DIR@/',
            '-MQ', '@OUTPUT@', '-MF', '@DEPFILE@',
            '@EXTRA_ARGS@',
            '@INPUT@',
            '-o', '@OUTPUT@'
        ])

    nasm_objs = nasm_gen.process(libdav1d_sources_asm)
else
    nasm_objs = []
endif

Henrik Gramner's avatar
Henrik Gramner committed
272 273 274 275 276 277 278 279 280 281 282 283 284 285
# Build a helper library for each bitdepth
bitdepth_objs = []
foreach bitdepth : dav1d_bitdepths
    bitdepth_lib = static_library(
        'dav1d_bitdepth_@0@'.format(bitdepth),
        libdav1d_tmpl_sources, config_h_target,
        include_directories: dav1d_inc_dirs,
        c_args: ['-DBITDEPTH=@0@'.format(bitdepth)] + stackalign_flag,
        install: false,
        build_by_default: false,
    )
    bitdepth_objs += bitdepth_lib.extract_all_objects()
endforeach

Marvin Scholz's avatar
Marvin Scholz committed
286
libdav1d = library('dav1d',
287
    libdav1d_sources, nasm_objs,
Marvin Scholz's avatar
Marvin Scholz committed
288
    version: '0.0.1',
289
    objects: [bitdepth_objs, entrypoints_objs],
Marvin Scholz's avatar
Marvin Scholz committed
290 291 292 293 294 295
    include_directories: dav1d_inc_dirs,
    c_args: [stackalign_flag],
    dependencies: thread_dependency,
    install: true
)

296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311
install_subdir('include/dav1d/', install_dir: 'include')

#
# dav1d cli tool
#
dav1d_sources = files(
    'tools/dav1d.c',
    'tools/dav1d_cli_parse.c',
    'tools/input/input.c',
    'tools/input/ivf.c',
    'tools/output/md5.c',
    'tools/output/output.c',
    'tools/output/y4m2.c',
    'tools/output/yuv.c'
)

312 313 314 315
if cc.get_id() == 'msvc'
    dav1d_sources += files('tools/compat/getopt.c')
endif

316 317 318
dav1d = executable('dav1d',
    dav1d_sources, rev_target,
    link_with: libdav1d,
319 320
    include_directories: [dav1d_inc_dirs, include_directories('tools')],
    install: true,
321 322
)

Marvin Scholz's avatar
Marvin Scholz committed
323 324 325 326 327 328 329 330 331 332
#
# pkg-config boilerplate
#
pkg_mod = import('pkgconfig')
pkg_mod.generate(libraries: libdav1d,
    version: '0.0.1',
    name: 'libdav1d',
    filebase: 'dav1d',
    description: 'AV1 decoding library'
)