meson.build 6.27 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31
# Copyright © 2018, VideoLAN and dav1d authors
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#
# 1. Redistributions of source code must retain the above copyright notice, this
#    list of conditions and the following disclaimer.
#
# 2. Redistributions in binary form must reproduce the above copyright notice,
#    this list of conditions and the following disclaimer in the documentation
#    and/or other materials provided with the distribution.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR
# ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

#
# Build definition for the dav1d library
#

# libdav1d source files
libdav1d_sources = files(
    'picture.c',
32
    'cpu.c',
33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54
    'data.c',
    'ref.c',
    'getbits.c',
    'obu.c',
    'decode.c',
    'cdf.c',
    'msac.c',
    'tables.c',
    'scan.c',
    'dequant_tables.c',
    'intra_edge.c',
    'lf_mask.c',
    'ref_mvs.c',
    'warpmv.c',
    'wedge.c',
    'qm.c',
)

# libdav1d bitdepth source files
# These files are compiled for each bitdepth with
# `BITDEPTH` defined to the currently built bitdepth.
libdav1d_tmpl_sources = files(
55
    'ipred_prepare_tmpl.c',
56 57 58 59 60 61 62 63 64
    'ipred_tmpl.c',
    'itx_tmpl.c',
    'lf_apply_tmpl.c',
    'loopfilter_tmpl.c',
    'mc_tmpl.c',
    'cdef_apply_tmpl.c',
    'cdef_tmpl.c',
    'lr_apply_tmpl.c',
    'looprestoration_tmpl.c',
65 66
    'recon_tmpl.c',
    'film_grain_tmpl.c',
67 68 69 70 71 72 73 74 75 76 77
)

# libdav1d entrypoint source files
# These source files contain library entry points and are
# built with the stack-realign flag set, where necessary.
libdav1d_entrypoints_sources = files(
    'lib.c',
    'thread_task.c'
)

# ASM specific sources
78
libdav1d_nasm_objs = []
79
if is_asm_enabled
80 81
    if (host_machine.cpu_family() == 'aarch64' or
        host_machine.cpu_family().startswith('arm'))
82

83 84 85 86
        libdav1d_sources += files(
            'arm/cpu.c',
        )
        libdav1d_tmpl_sources += files(
87
            'arm/looprestoration_init_tmpl.c',
88
            'arm/mc_init_tmpl.c',
89 90
        )
        if host_machine.cpu_family() == 'aarch64'
91
            libdav1d_sources += files(
92
                'arm/64/looprestoration.S',
93
                'arm/64/mc.S',
94 95
            )
        elif host_machine.cpu_family().startswith('arm')
96
            libdav1d_sources += files(
97
                'arm/32/mc.S',
98 99 100
            )
        endif
    elif host_machine.cpu_family().startswith('x86')
101

102 103 104
        libdav1d_sources += files(
            'x86/cpu.c',
        )
105

106
        libdav1d_tmpl_sources += files(
107
            'x86/cdef_init_tmpl.c',
108 109 110 111 112
            'x86/ipred_init_tmpl.c',
            'x86/itx_init_tmpl.c',
            'x86/loopfilter_init_tmpl.c',
            'x86/looprestoration_init_tmpl.c',
            'x86/mc_init_tmpl.c',
113
        )
114

115 116
        # NASM source files
        libdav1d_sources_asm = files(
117
            'x86/cdef.asm',
118
            'x86/cpuid.asm',
119
            'x86/ipred.asm',
120
            'x86/itx.asm',
121
            'x86/loopfilter.asm',
122
            'x86/looprestoration.asm',
123
            'x86/mc.asm',
124
            'x86/mc_ssse3.asm',
125
            'x86/itx_ssse3.asm',
126
            'x86/ipred_ssse3.asm',
127 128 129 130 131
        )

        # Compile the ASM sources with NASM
        libdav1d_nasm_objs = nasm_gen.process(libdav1d_sources_asm)
    endif
132 133 134 135 136 137 138 139
endif



#
# Windows .rc file
#

140
if host_machine.system() == 'windows' and get_option('default_library') != 'static'
141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172
    winmod = import('windows')
    rc_data = configuration_data()
    rc_data.set('VERSION_MAJOR', dav1d_version_major)
    rc_data.set('VERSION_MINOR', dav1d_version_minor)
    rc_data.set('VERSION_REVISION', dav1d_version_revision)
    rc_data.set('VERSION_EXTRA', '0')
    rc_data.set('COPYRIGHT_YEARS', '2018')

    rc_file = configure_file(
        input : 'dav1d.rc.in',
        output : 'dav1d.rc',
        configuration : rc_data
    )

    libdav1d_rc_obj = winmod.compile_resources(rc_file)
else
    libdav1d_rc_obj = []
endif




#
# Library definitions
#

# Helper library for dav1d entrypoints
libdav1d_entrypoints_objs = static_library('dav1d_entrypoint',
    libdav1d_entrypoints_sources,
    rev_target,

    include_directories : dav1d_inc_dirs,
173
    dependencies: [stdatomic_dependency],
174
    c_args : [stackalign_flag, stackrealign_flag],
175 176 177 178 179 180 181 182 183 184 185
    install : false,
    build_by_default : false,
).extract_all_objects()

# Helper library for each bitdepth
libdav1d_bitdepth_objs = []
foreach bitdepth : dav1d_bitdepths
    libdav1d_bitdepth_objs += static_library(
        'dav1d_bitdepth_@0@'.format(bitdepth),
        libdav1d_tmpl_sources, config_h_target,
        include_directories: dav1d_inc_dirs,
186
        dependencies : [stdatomic_dependency],
187 188 189 190 191 192
        c_args : ['-DBITDEPTH=@0@'.format(bitdepth)] + stackalign_flag,
        install : false,
        build_by_default : false,
    ).extract_all_objects()
endforeach

193 194 195 196 197 198 199 200
# The final dav1d library
if host_machine.system() == 'windows'
    dav1d_soversion = ''
else
    dav1d_soversion = dav1d_version_major
endif

libdav1d = library('dav1d',
201 202 203 204 205 206 207 208 209 210
    libdav1d_sources,
    libdav1d_nasm_objs,
    libdav1d_rc_obj,

    objects : [
        libdav1d_bitdepth_objs,
        libdav1d_entrypoints_objs
        ],

    include_directories : dav1d_inc_dirs,
211 212 213 214 215
    dependencies : [
        stdatomic_dependency,
        thread_dependency,
        thread_compat_dep,
        ],
216 217
    c_args : [stackalign_flag],
    version : meson.project_version(),
218
    soversion : dav1d_soversion,
219 220
    install : true,
)
221 222 223 224 225 226 227 228 229 230 231

#
# Generate pkg-config .pc file
#
pkg_mod = import('pkgconfig')
pkg_mod.generate(libraries: libdav1d,
    version: meson.project_version(),
    name: 'libdav1d',
    filebase: 'dav1d',
    description: 'AV1 decoding library'
)